Описание библиотеки Haskell 98: Комплексные числа Описание Haskell 98
наверх | назад | вперед | содержание | предметный указатель функций

13  Комплексные числа


module  Complex ( 
    Complex((:+)), realPart, imagPart, conjugate, 
    mkPolar, cis, polar, magnitude, phase ) where

infix  6  :+

data  (RealFloat a)     => Complex a = !a :+ !a

realPart, imagPart      :: (RealFloat a) => Complex a -> a
conjugate         :: (RealFloat a) => Complex a -> Complex a
mkPolar         :: (RealFloat a) => a -> a -> Complex a
cis         :: (RealFloat a) => a -> Complex a
polar         :: (RealFloat a) => Complex a -> (a,a)
magnitude, phase        :: (RealFloat a) => Complex a -> a

instance  (RealFloat a) => Eq         (Complex a)  where ...
instance  (RealFloat a) => Read       (Complex a)  where ...
instance  (RealFloat a) => Show       (Complex a)  where ...
instance  (RealFloat a) => Num        (Complex a)  where ...
instance  (RealFloat a) => Fractional (Complex a)  where ...
instance  (RealFloat a) => Floating   (Complex a)  where ...

Комплексные числа являются алгебраическим типом. Конструктор (:+) образует комплексное число из его действительной и мнимой прямоугольных компонент. Этот конструктор является строгим: если действительной или мнимой частью числа является _|_, все число является _|_. Комплексное число может быть также образовано из полярных компонент величины и фазы с помощью функции mkPolar. Функция cis генерирует комплексное число из угла t. С другой стороны, cis t возвращает комплексное значение с величиной 1 и фазой t (по модулю 2p).

Функция polar принимает в качестве аргумента комплексное число и возвращает пару (величина, фаза) в канонической форме: величина является неотрицательной, а фаза находится в диапазоне (-p, p]; если величина равна нулю, то фаза также равна нулю.

Функции realPart и imagPart извлекают прямоугольные компоненты комплексного числа, а функции magnitude и phase извлекают полярные компоненты комплексного числа. Функция conjugate вычисляет сопряженное комплексное число обычным способом.

Величина и знак комплексного числа определены следующим образом:

abs z   =  magnitude z :+ 0
signum 0   =  0
signum z@(x:+y)   =  x/r :+ y/r  where r = magnitude z

То есть abs z --- это число с величиной z, но ориентированное в направлении положительной действительной полуоси, тогда как signum z имеет фазу z, но единичную величину.

13.1  Библиотека Complex



module Complex(Complex((:+)), realPart, imagPart, conjugate, mkPolar,
               cis, polar, magnitude, phase)  where

infix  6  :+

data  (RealFloat a)     => Complex a = !a :+ !a  deriving (Eq,Read,Show)


realPart, imagPart :: (RealFloat a) => Complex a -> a
realPart (x:+y)  =  x
imagPart (x:+y)  =  y

conjugate  :: (RealFloat a) => Complex a -> Complex a
conjugate (x:+y) =  x :+ (-y)

mkPolar  :: (RealFloat a) => a -> a -> Complex a
mkPolar r theta  =  r * cos theta :+ r * sin theta

cis  :: (RealFloat a) => a -> Complex a
cis theta  =  cos theta :+ sin theta

polar  :: (RealFloat a) => Complex a -> (a,a)
polar z  =  (magnitude z, phase z)

magnitude :: (RealFloat a) => Complex a -> a
magnitude (x:+y) =  scaleFloat k
     (sqrt ((scaleFloat mk x)^2 + (scaleFloat mk y)^2))
    where k  = max (exponent x) (exponent y)
          mk = - k

phase :: (RealFloat a) => Complex a -> a
phase (0 :+ 0) = 0
phase (x :+ y) = atan2 y x


instance  (RealFloat a) => Num (Complex a)  where
    (x:+y) + (x':+y') =  (x+x') :+ (y+y')
    (x:+y) - (x':+y') =  (x-x') :+ (y-y')
    (x:+y) * (x':+y') =  (x*x'-y*y') :+ (x*y'+y*x')
    negate (x:+y) =  negate x :+ negate y
    abs z =  magnitude z :+ 0
    signum 0 =  0
    signum z@(x:+y) =  x/r :+ y/r  where r = magnitude z
    fromInteger n =  fromInteger n :+ 0

instance  (RealFloat a) => Fractional (Complex a)  where
    (x:+y) / (x':+y') =  (x*x''+y*y'') / d :+ (y*x''-x*y'') / d
   where x'' = scaleFloat k x'
 y'' = scaleFloat k y'
 k   = - max (exponent x') (exponent y')
 d   = x'*x'' + y'*y''

    fromRational a =  fromRational a :+ 0

instance  (RealFloat a) => Floating (Complex a) where
    pi             =  pi :+ 0
    exp (x:+y)     =  expx * cos y :+ expx * sin y
                      where expx = exp x
    log z          =  log (magnitude z) :+ phase z

    sqrt 0         =  0
    sqrt z@(x:+y)  =  u :+ (if y < 0 then -v else v)
                      where (u,v) = if x < 0 then (v',u') else (u',v')
                            v'    = abs y / (u'*2)
                            u'    = sqrt ((magnitude z + abs x) / 2)

    sin (x:+y)     =  sin x * cosh y :+ cos x * sinh y
    cos (x:+y)     =  cos x * cosh y :+ (- sin x * sinh y)
    tan (x:+y)     =  (sinx*coshy:+cosx*sinhy)/(cosx*coshy:+(-sinx*sinhy))
                      where sinx  = sin x
                            cosx  = cos x
                            sinhy = sinh y
                            coshy = cosh y

    sinh (x:+y)    =  cos y * sinh x :+ sin  y * cosh x
    cosh (x:+y)    =  cos y * cosh x :+ sin y * sinh x
    tanh (x:+y)    =  (cosy*sinhx:+siny*coshx)/(cosy*coshx:+siny*sinhx)
                      where siny  = sin y
                            cosy  = cos y
                            sinhx = sinh x
                            coshx = cosh x

    asin z@(x:+y)  =  y':+(-x')
                      where  (x':+y') = log (((-y):+x) + sqrt (1 - z*z))
    acos z@(x:+y)  =  y'':+(-x'')
                      where (x'':+y'') = log (z + ((-y'):+x'))
                            (x':+y')   = sqrt (1 - z*z)
    atan z@(x:+y)  =  y':+(-x')
                      where (x':+y') = log (((1-y):+x) / sqrt (1+z*z))

    asinh z        =  log (z + sqrt (1+z*z))
    acosh z        =  log (z + (z+1) * sqrt ((z-1)/(z+1)))
    atanh z        =  log ((1+z) / sqrt (1-z*z))


Описание Haskell 98
наверх | назад | вперед | содержание | предметный указатель функций
Декабрь 2002